PrSAT: Some Examples

First, load the PrSAT package:

<<PrSAT`

Example #1:  X, Y, Z pairwise independent, but not independent

MODEL1=
PrSAT[
{
Pr[X∧Y]==Pr[X] Pr[Y],
Pr[X∧Z]==Pr[X] Pr[Z],
Pr[Z∧Y]==Pr[Z] Pr[Y],
Pr[X∧Y∧Z]≠Pr[X] Pr[Y] Pr[Z]
},
Probabilities->Regular
]

TruthTable[MODEL1]

EvaluateProbability[
{
Pr[X∧Y]==Pr[X] Pr[Y],
Pr[X∧Z]==Pr[X] Pr[Z],
Pr[Z∧Y]==Pr[Z] Pr[Y],
Pr[X∧Y∧Z]≠Pr[X] Pr[Y] Pr[Z]
},MODEL1]

Example #2:  s violates (†)

s[h_,e_]:=Pr[h|e]-Pr[h|¬e];

MODEL2 = 
PrSAT[
{
Pr[ℍ | 𝔼1]>Pr[ℍ | 𝔼2],
s[ℍ,𝔼1]<s[ℍ,𝔼2]
},
Probabilities->Regular]

TruthTable[MODEL2]

EvaluateProbability[
{
Pr[ℍ | 𝔼1]>Pr[ℍ | 𝔼2],
s[ℍ,𝔼1]<s[ℍ,𝔼2]
},MODEL2]

Note: d satisfies (†)

d[h_,e_]:=Pr[h|e]-Pr[h];

PrSAT[
{
Pr[ℍ | 𝔼1]≥Pr[ℍ | 𝔼2],
d[ℍ,𝔼1]<d[ℍ,𝔼2]
}
]

Example #3: A Counterexample Requiring 4-Events (Douven)

Question: Given a finite set S of propositions such that (1) each proposition H in S is correlated with the conjunction of the members of any non-empty of subset of S that does not contain H, is (2) the conjunction of the members of any non-empty subset S' of S correlated with the conjunction of any non-empty subset S'' of S not overlapping with S'?  

Answer: No.  Note: the answer is YES for 3-event spaces.  So, we assume a four-event probabilitiy space, over the propositions {X, Y, Z, W}.  To try to find a 4-element countermodel, we first represent condition (1):

C1:=
{
Pr[X | Y] > Pr[X],
Pr[X | Z] > Pr[X],
Pr[X | W] > Pr[X],
Pr[Y | Z]>Pr[Y],
Pr[Y | W]>Pr[Y],
Pr[Z | W]>Pr[Z],
Pr[X | Y∧Z]>Pr[X],
Pr[X | Y∧W]>Pr[X],
Pr[X | Z∧W]>Pr[X],
Pr[Y | X∧Z]>Pr[Y],
Pr[Y | X∧W]>Pr[Y],
Pr[Y | Z∧W]>Pr[Y],
Pr[Z | X∧Y]>Pr[Z],
Pr[Z | X∧W]>Pr[Z],
Pr[Z | Y∧W]>Pr[Z],
Pr[X | Y∧Z∧W]>Pr[X],
Pr[Y | X∧Z∧W]>Pr[Y],
Pr[Z | X∧Y∧W]>Pr[Z]
};

Now, the key will be trying to find models in which C1 (i.e., all the inequalities in C1) holds, and in which at least one of the following equalities holds (these would, of course, be models in which (2) fails):

C2:=
{
Pr[X∧Y | Z∧W] ==Pr[X∧Y],
Pr[X∧Z | Y∧W] ==Pr[X∧Z],
Pr[Y∧Z | X∧W] ==Pr[Y∧Z]
}

In fact, we'll find a model in which all the equations in C2  hold, using our PrSAT function, as follows:

MODEL3 =
 PrSAT[

Union[C1,C2],

Probabilities->Regular
]

TruthTable[MODEL3]

EvaluateProbability[
{
Union[C1,C2]
},MODEL3]

"Proving" Theorems

Bayes's Theorem is trivial:

PrSAT[
{
Pr[X | Y]≠((Pr[Y | X] Pr[X])/(Pr[Y | X] Pr[X]+Pr[Y | ¬X] Pr[¬X]))
}
]

Popper-Miller Theorem "Additivity of d-Confirmation" Theorem is trivial:

PrSAT[
{
d[ℍ,𝔼]≠d[ℍ∨𝔼,𝔼]+d[ℍ∨¬𝔼,𝔼]
}
]

PrSAT[
{
d[ℍ∨¬𝔼,𝔼]>0
}
]

PrSAT[
{
d[ℍ,𝔼]≠d[ℍ∧𝔼,𝔼]+d[ℍ∧¬𝔼,𝔼]
}
]

PrSAT[
{
d[ℍ∧¬𝔼,𝔼]>0
}
]

Note: Popper-Miller Theorem fails for r (first pointed out by Redhead)

r[h_,e_]:=Pr[h|e]/Pr[h];

MODEL4=PrSAT[
{
r[ℍ,𝔼]≠r[ℍ∨𝔼,𝔼]+r[ℍ∨¬𝔼,𝔼]
},
Probabilities->Regular
]

TruthTable[MODEL4]

Wagner's "Probabilistic Modus Tollens" Theorem is trivial

PrSAT[
{
((1-Pr[𝔼|ℍ]-Pr[¬𝔼])/(1-Pr[𝔼|ℍ]))≥((Pr[𝔼|ℍ]+Pr[¬𝔼]-1)/(Pr[𝔼|ℍ])),((1-Pr[𝔼|ℍ]-Pr[¬𝔼])/(1-Pr[𝔼|ℍ]))>Pr[¬ℍ]
}
]

PrSAT[
{
((Pr[𝔼|ℍ]+Pr[¬𝔼]-1)/(Pr[𝔼|ℍ]))≥((1-Pr[𝔼|ℍ]-Pr[¬𝔼])/(1-Pr[𝔼|ℍ])),((Pr[𝔼|ℍ]+Pr[¬𝔼]-1)/(Pr[𝔼|ℍ]))>Pr[¬ℍ]
}
]